Customizing LAT Characteristics

If both a Table of Contents and Search form are not displayed in separate frames along with this one, you may wish to redisplay this book in a frameset, beginning with the first page.

HP OpenVMS System Manager's Manual, Volume 2:...

Managing the LAT Software

Starting Up the LAT Protocol

Managing the LATACP Database Size

Customizing LAT Characteristics

To define special LAT characteristics for your node, edit the site-specific command procedure SYS$MANAGER:LAT$SYSTARTUP.COM. This command procedure contains LATCP commands that define LAT characteristics. LAT$SYSTARTUP.COM is invoked when you execute the LAT$STARTUP command procedure. As explained in Starting Up the LAT Protocol, you typically execute LAT$STARTUP.COM from the general-purpose, site-specific startup command procedure.

If you want your node to be a LAT service node that only supports incoming connections from interactive terminals, editing LAT$SYSTARTUP.COM is not necessary. You can assign a service name and other characteristics by specifying parameters when you invoke the command procedure SYS$STARTUP:LAT$STARTUP, as described in Starting Up the LAT Protocol.

However, you can edit LAT$SYSTARTUP.COM to add LATCP commands that customize LAT characteristics for your node, for example:

Task For More Information

Create more than one service
Creating Additional Services

Create logical ports for special application services and printers
Setting Up Ports

Enable queued incoming requests
Queuing Incoming Requests

Enable outgoing LAT connections to support the SET HOST/LAT command
Enabling Outgoing LAT Connections

Tailor node characteristics¹
Sample Edited LAT$SYSTARTUP.COM Procedure

Task	For More Information
Create more than one service	Creating Additional Services
Create logical ports for special application services and printers	Setting Up Ports
Enable queued incoming requests	Queuing Incoming Requests
Enable outgoing LAT connections to support the SET HOST/LAT command	Enabling Outgoing LAT Connections
Tailor node characteristics¹	Sample Edited LAT$SYSTARTUP.COM Procedure

Do not edit the command procedures LAT$STARTUP.COM and LAT$CONFIG.COM. These are procedures supplied by HP to perform functions necessary for the LAT protocol to run correctly. Edit only LAT$SYSTARTUP.COM to define LAT characteristics specific to your site.

If you edit LAT$SYSTARTUP.COM, you should add only LATCP commands. In addition, you should conform to the order of commands in the template file SYS$MANAGER:LAT$SYSTARTUP.TEMPLATE. Sample Edited LAT$SYSTARTUP.COM Procedure provides a sample edited LAT$SYSTARTUP procedure. The HP OpenVMS System Management Utilities Reference Manual: A--L contains full descriptions of all the LATCP commands you can include in LAT$SYSTARTUP.COM.

Creating Additional Services

The LAT$SYSTARTUP.COM procedure provided by HP creates one service. This can be a primary service, one through which users can access the general computing environment. It can also be a special application service, such as a data entry program or an online news service.

You can also create a limited service with a fixed number of LTA devices, as described in Setting Up Limited Services.

The LAT$SYSTARTUP.COM procedure creates the service with the same name as that of your node, unless you specify a unique service name as an argument to the @SYS$STARTUP:LAT$STARTUP.COM command, as explained in Starting Up the LAT Protocol.

How to Perform This Task

To create services in addition to the one provided in LAT$SYSTARTUP.COM, use the CREATE SERVICE commands, which you can add to LAT$SYSTARTUP.COM. Note that if you create an application service, HP recommends that you assign the name of the application program. For more information about the LATCP command CREATE SERVICE, refer to the HP OpenVMS System Management Utilities Reference Manual .

Example

The following example creates the application service NEWS on the local node:

$ LCP :== $LATCP
$ LCP CREATE SERVICE /APPLICATION NEWS

Setting Up Ports

The LAT$SYSTARTUP.COM file provided by HP includes sample commands to create logical ports on the service node and associates them with physical ports or services on the terminal server node. These ports can be used for application services and remote printers.

How to Perform This Task

To create ports, enable the sample commands by removing the exclamation points (!) that precede them in the LAT$SYSTARTUP.COM file, or add similar CREATE PORT and SET PORT commands to that file to meet your needs. For information about the LATCP commands CREATE PORT and SET PORT, refer to the HP OpenVMS System Management Utilities Reference Manual: A--L.

HP strongly recommends that you create application ports and dedicated ports after the LATCP command SET NODE/STATE=ON is executed. This minimizes nonpaged pool memory usage and eliminates the possibility of creating duplicate ports.

Note that you may encounter the following error when attempting to create an application port (with a command such as LCP CREATE PORT LTA5001:/APPLICATION, for example):

%LAT-W-CMDERROR, error reported by command executor
-SYSTEM-F-DUPLNAM, duplicate name

This error indicates that the LAT application port you are trying to create is already created by some other application. This application could be LATCP itself (LATCP's port, LATCP$MGMT_PORT, is used to communicate with LTDRIVER).

To avoid this error, make sure the SET NODE/STATE=ON command is executed before any commands that create application ports or dedicated ports. You can also use the LATCP command SET NODE/DEVICE_SEED. For more information about the SET NODE/DEVICE_SEED command, refer to the HP OpenVMS System Management Utilities Reference Manual: A--L .

Setting Up Printers

If you set up a port for a printer, you must also perform the following tasks:

Create a spooled output queue for the printer.

Add a command to start the queue to the startup command procedure that starts your queues, or to the general-purpose, site-specific startup command procedure.

These tasks are described in the HP OpenVMS System Manager's Manual, Volume 1: Essentials.

Setting Up Special Application Services

To establish a special application service, include the /DEDICATED qualifier when defining a LAT port. The application program to which the service connects must define the same dedicated port. For example, the following commands set up ports for an application service called NEWS:

$ LCP :== $LATCP
$ LCP CREATE PORT LTA333:/DEDICATED 
$ LCP SET PORT LTA333:/SERVICE=NEWS

Before application services can be available to user terminals on the LAT network, you must start the application program. You usually add commands to SYLOGIN.COM to do this.

Setting Up Limited Services

Application services with dedicated ports allow you to create a predetermined number of LTA devices (LAT terminals, for example) that are under the control of a process supplied by the system. In that environment, however, the user cannot log in to the service because no way exists for dedicated LTA devices to run the system login image (LOGINOUT.EXE).

You can create a limited service that allows users to log in to a predetermined number of LTA devices associated with that limited service. When all those devices are in use, the LAT software will reject additional connection requests to that service, as indicated by "service in use" error messages. Creating a limited service in this way allows you to control the number of LAT users on your system. (Note, however, that you cannot control which LTA device will be assigned when a user connects to the limited service.)

The following example sets up a limited service with two predetermined LTA devices:

$ LCP :== $LATCP
$ LCP CREATE SERVICE /LIMITED RESTRICTED
$ LCP CREATE PORT LTA100 /LIMITED
$ LCP CREATE PORT LTA101 /LIMITED
$ LCP SET PORT LTA100 /SERVICE=RESTRICTED
$ LCP SET PORT LTA101 /SERVICE=RESTRICTED

When a user attempts to connect to the limited service named RESTRICTED, the LAT software will choose either LTA100 or LTA101 (whichever is available first) and complete the user connection. The user can then log in to that system. If another user connects to the service, that second connection attempt will be assigned to the remaining LTA device. The user can then log in to that second system. When the two devices associated with the limited service named RESTRICTED are both in use, any subsequent attempts to connect to that service will be rejected, as indicated by the "service in use" error message.

When a user logs out of the system (LTA100 or LTA101), that LTA device is not deleted. Instead, it is reset to accept the next connection request to the limited service.

Queuing Incoming Requests

By default, incoming requests to limited or application services are queued. This means that if you attempt to connect to a limited or application service (by using a terminal server port with forward queuing enabled or by entering the DCL command SET HOST/LAT/QUEUE), the LAT software will queue, rather than reject, this connection request if the service has no available ports.

How to Perform This Task

You can set up and manage a service that queues incoming connect requests as follows:

Use the LATCP command SHOW SERVICE to determine whether the service has queuing enabled or disabled.

If queuing is disabled, use the SET SERVICE /QUEUED command to enable queuing.

Use the SET NODE /QUEUE_LIMIT=n command on the local node to control the number of free queue slots (where n is between 0 and 200).

Use the SHOW QUEUE_ENTRY [queue-entry-id] command to view entries in the local queue.

Use the DELETE QUEUE_ENTRY [queue-entry-id] command to delete an entry from the local queue.

Refer to the HP OpenVMS System Management Utilities Reference Manual: A--L for more detailed descriptions of the LATCP commands and qualifiers you use to support queued requests.

Example

The following example shows how to enable queuing on your system:

$ LCP :== $LATCP
$ LCP SET SERVICE /QUEUE

If a system is configured to handle queued connect requests, that system must be set up as follows to avoid possible queue connection failures:

Incoming and outgoing connections must be enabled.

User group codes and service group codes must be identical.

Enabling Outgoing LAT Connections

By default, outgoing LAT connections are disabled on a node. To allow users to use the SET HOST/LAT connection to establish LAT connections from the node, you must edit LAT$SYSTARTUP.COM to enable outgoing connections. For more details on using the SET HOST/LAT command for outgoing LAT connections, refer to the description of that command in the HP OpenVMS DCL Dictionary.

Commands to enable outgoing connections are included in the LAT$SYSTARTUP.COM file provided by HP. Enable the command of your choice by removing the exclamation point (!) that precedes it, or add a similar command to meet your needs. For more information, refer to the /CONNECTIONS and /USER_GROUPS qualifiers to the LATCP command SET NODE in the HP OpenVMS System Management Utilities Reference Manual: A--L.

To attain optimal SET HOST/LAT performance and forward port performance, you should set the system parameter TTY_ALTYPAHD to 1500 and reboot.

If you want to set up your node only as a service node with incoming connections enabled, editing LAT$SYSTARTUP.COM is not necessary. However, you might edit LAT$SYSTARTUP.COM to do one or more of the following tasks:

Create more than one service on a node

Create special application services

Set up LAT printers

Enable outgoing LAT connections (to allow a node to act as a terminal server node)

Tailor node characteristics; for example, to assign special service announcements or connections to the LAN

Sample Edited LAT$SYSTARTUP.COM Procedure

The following example is a sample of an edited LAT$SYSTARTUP.COM procedure that creates services, creates and sets ports, and sets nodes to allow incoming and outgoing connections.

$!
$!    LAT$SYSTARTUP.COM -- LAT Startup Commands Specific to Site
$!
$!    Use this command procedure to customize the LAT characteristics for
$!    the local node.  These commands, which should serve as examples,
$!    will set up a LAT service name SYS$NODE and default identification
$!    SYS$ANNOUNCE.  The LAT service name and identification will default
$!    to SYS$NODE and SYS$ANNOUNCE unless you specify a service name and
$!    identification as arguments to the command line that invokes 
$!    LAT$STARTUP.COM:
$!                    $ @SYS$STARTUP:LAT$STARTUP
$!
$!    You can specify other node and service characteristics (such as group
$!    codes) as arguments to this command line, as shown below.
$!
$!        Argument     Function
$!        ---------    --------
$!
$!           P1        Name of the service to be created.  If not supplied, a
$!                     service will be created with the same name as the node.
$!
$!        P2,P3,P4     Parameters and qualifiers to the SET NODE command.
$!
$!           P5        Parameters and qualifiers to the SET SERVICE command.
$!                     P5 is only used if P1 is specified.  More than one
$!                     argument may be supplied by enclosing the string in
$!                     quotes.
$!
$!    Example: $ @SYS$STARTUP:LAT$STARTUP HAWK "/IDENTIFICATION=" -
$!			   """""Development node"""""$!
$!    Please review and edit this file for possible additions and deletions
$!    that you wish to make.  Future software updates will not overwrite the
$!    changes made to this file.
$!
$ required_privileges = "OPER"
$ prev_privs = f$setprv(required_privileges)
$ if .not. f$privilege(required_privileges) then goto no_privileges
$ lcp := $latcp
$!
$! ---------------------  Modify Node Characteristics  ------------------------
$!
$ lcp set node 'p2' 'p3' 'p4'
$!
$! Some examples:
$!
$! ** Allow incoming connections only
$!
$! lcp set node /connections=incoming /groups=(enable=(12,40,43,73),disable=0)
$! lcp set node /connections=incoming /groups=enable=(0-255)
$!
$ LCP SET NODE /CONNECTIONS=INCOMING /GROUPS=(ENABLE=(12,40,43,73),DISABLE=0)
$!
$! ** Allow outgoing connections only
$!
$! lcp set node /connections=outgoing /user_groups=enable=(24,121-127)
$! lcp set node /connections=outgoing /user_groups=(enable=0-255) /node_limit=50
$!
$! ** Enable incoming and outgoing connections
$!
$! lcp set node /connections=both /group=enable=(43,73) /user=enable=(44,56)
$! lcp set node /connections=both /group=enable=(0-255) /user=enable=(0-255)
$!
$!
$! --------------------  Modify Service Characteristics  ----------------------
$!
$ if p1 .eqs. ""
$ then
$    lcp create service
$ else
$     lcp create service 'p1' 'p5'
$ endif
$! -------------------------  Start LAT Protocol  -----------------------------
$!
$ lcp set node /state=on
$!
$!
$! -------------------------  Create and Map Ports  ---------------------------
$! 
$! Some examples:
$!
$! lcp create port lta101: /dedicated
$! lcp create port lta102: /application
$! lcp create port lta103: /application
$! lcp create port /nolog/logical=(name=ln03$mgmt, table=system, mode=executive)
$ 
$ LCP CREATE PORT LTA1: /NOLOG
$ LCP CREATE PORT LTA20: /NOLOG
$ 
$! lcp set port lta101: /dedicated /service=graphics
$! lcp set port lta102: /node=server_1 /port=port_1
$! lcp set port lta103: /node=server_2 /service=laser
$! lcp set port ln03$mgmt: /node=server_3 /service=ln03_printers
$!
$ LCP SET PORT LTA1: /APPLICATION/NODE=TERM_SERVER_1 /PORT=PORT_6
$ LCP SET PORT LTA20: /APPLICATION/NODE=TERM_SERVER_2 /PORT=PORT_6
$!
$exit:
$ prev_privs = f$setprv(prev_privs)
$ exit
$!
$no_privileges:
$ write sys$output "Insufficient privileges to execute LATCP commands."
$ write sys$output "Requires ",required_privileges," privileges."
$ goto exit

Footnotes

1 For example, to assign special service announcements or LAN links (using the SET NODE and SET LINK commands).

( Number takes you back )

Starting Up the LAT Protocol

Managing the LATACP Database Size