Everhart,Glenn
From:	CROBW@alpha4.curtin.edu.au
Sent:	Tuesday, March 31, 1998 7:06 PM
To:	Info-VAX@Mvb.Saic.Com
Subject:	Backup: How to set its account values
After having had WAITIDLEBCB errors from Backup, we were strongly advised to
conform to the recommendations for setting the account parameters for the
account from which backups are run. I put together the following command
procedure to facilitate this. I hope you find it useful.

>------------------ cut here ---------------<
$! SET-BACKUP-ACCOUNT.COM
$!
$! Robert J Wright, Curtin University Computing Centre, 1998.
$!
$! The following is intended as a quick way to setthe BACKUP account's
$! parameters to proper values relative to one another. 
$!
$! Note that in a clustered environment with differently sized nodes, either
$! a node-specific account must be used on each node, or the common account
$!should be sized on the smallest node on which Backup will be run.
$
$ s = f$verify(0)
$
$ node = f$getsyi("nodename")
$ inquire/nopunc ok "The values will be computed for node ''node', OK? "
$
$ wsmax = f$getsyi("wsmax")*512/f$getsyi("page_size")	! (old style pages)
$ channelcnt = f$getsyi("channelcnt")
$
$! The following calculations are based on Table 10-4, Sytems Managers' Manual
$! as at VMS 7.1
$
$ wsquota = wsmax
$ wsextent = wsmax
$ pgflquota = wsmax
$ fillm = channelcnt - 1
$
$ f3 = 3*fillm
$ if f3 .gt. 4096
$ then
$   diolm = f3
$ else
$   diolm = 4096
$ endif
$
$ astlm = 4096
$ if 3*fillm .gt. astlm then astlm = 3*fillm
$ if astlm .lt. (diolm+100) then astlm = diolm + 100
$
$ biolm = fillm
$ bytlm = (256*fillm) + (6*diolm)
$ enqlm = fillm + 1
$
$ inquire ac "Name of Backup account (e.g., CBCKUP)"
$ if ac .eqs. "" then exit
$ uaf := @cu_command:uaf.com
$ write sys$output "/wsquota=''wsquota'
$ write sys$output "/wsextent=''wsextent'
$ write sys$output "/pgflquota=''pgflquota'
$ write sys$output "/fillm=''fillm'
$ write sys$output "/diolm=''diolm'
$ write sys$output "/astlm=''astlm'
$ write sys$output "/biolm=''biolm'
$ write sys$output "/bytlm=''bytlm'
$ write sys$output "/enqlm=''enqlm'
$ write sys$output ""
$ Inquire yes "The above values will be used. Go ahead?"
$ if .not. yes then exit
$ uaf modify 'ac' /wsquota='wsquota/wsextent='wsextent' -
                  /pgflquota='pgflquota'/fillm='fillm'/diolm='diolm' -
		  /astlm='astlm'/biolm='biolm'/bytlm='bytlm' -
	          /enqlm='enqlm'
$ exit 'f$verify(s)

--
Robert J Wright  Virtual Memory Systematist and Digital Command Linguist
Curtin University Computing Centre.            (+61-8)9266-7385 voice (24hrs)
Kent Street, Bentley 6102, Western Australia.  (+61-8)9266-2673 fax
GPO Box U1987, Perth 6845, Western Australia.  R.Wright@curtin.edu.no_junk
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Music is the arithmetic of sounds as optics is the geometry of light.
	-Claude Debussy