Article 156294 of comp.os.vms:
Seamus Montgomery <seamusm@shorts.co.uk> writes:

>Try finding a relevant .exe in SYS$MESSAGE, eg netwrkmsg.exe.

or better yet, let the computer look for you:

$       save_ver = 'f$verify(0)'
$	ws := write sys$output
$       msgtxt = f$message(p1)
$       ws "''msgtxt'"
$       msglen = f$length(msgtxt)
$       badmsg = 0
$       if f$locate("%NONAME-", msgtxt) .lt. msglen then badmsg = 1
$       if f$locate("-NOMSG,",  msgtxt) .lt. msglen then badmsg = 1
$       if .not. badmsg then goto LEAVE
$       ws "checking other message files . . ."
$ MSGLOOP:
$       msgfs = f$search("SYS$MESSAGE:*.EXE")
$       if msgfs .eqs. "" then goto MSGDONE
$       set message 'msgfs'
$       msgtxt = f$message(p1)
$       badmsg = 0
$       if f$locate("%NONAME-", msgtxt) .lt. msglen then badmsg = 1
$       if f$locate("-NOMSG,",  msgtxt) .lt. msglen then badmsg = 1
$       if badmsg
$       then
$               if save_ver
$               then
$                       ws "the condition ''p1' is not in message file ''msgfs'"
$               endif
$       else
$               tmpfs = f$parse(msgfs,,,"NAME") + f$parse(msgfs,,,"TYPE")
$               ws ""
$               ws "in message file ''tmpfs', the condition ''p1' translates to"
$               ws "    ''msgtxt'"
$       endif
$       goto MSGLOOP
$ MSGDONE:
$       set message /delete
$       goto LEAVE
$ LEAVE:
$	exit 1 + 0 * f$verify(save_ver)

ok
dpm
-- 
David P. Murphy             mailto:murphy@connor.datametrics.com     (work)
systems programmer          mailto:dpm@access.digex.net          (personal)
                            http://www.access.digex.net/~dpm
COGITO ERGO DISCLAIMUM       ftp://ftp.access.digex.net/pub/access/dpm


