From: alanb@cloud9.net
Sent: Wednesday, October 03, 2001 2:37 PM
To: Info-VAX@Mvb.Saic.Com
Subject: Re: Reset error account on Alpha

Here's a macro program; I don't remember where I got it. I relieve
myself of all responsibility for system crashes.

;
; Hack to zero the system and device error counters on OpenVMS Alpha
;
; Jur van der Burg
; Compaq
;
; $ macro zeroerr
; $ link/sysexe zeroerr
;
        .library        'sys$library:lib.mlb'

        $ucbdef
        $ssdef

        .entry  zeroerr,^m<>

        $cmkrnl_s       routin=zero
        ret

        .entry  zero,^m<>

        movab   nocrash,(fp)
        movl    g^ctl$gl_pcb,r4
        jsb     g^sch$iolockw
        clrl    r11

10$:    jsb     g^ioc$scan_iodb
        blbc    r0,20$
        clrl    ucb$l_errcnt(r10)
        brb     10$

20$:    clrl    g^exe$gl_memerrs
        clrl    g^exe$gl_mchkerrs
        movl    g^ctl$gl_pcb,r4
        jsb     g^sch$iounlock
        setipl  #0
        movzbl  #ss$_normal,r0
        ret

        .entry  nocrash,^m<>

        setipl  #0
        $exit_s

        .end    zeroerr






norm.raphael@jamesbury.com wrote in message news:<C2256ADA.005148A0.00@jklh21.valmet.com>...
> There is an unsupported utility from Hardware Support called ZDEC
> (Zero Device Error Count) that will do this, device by device.
> 
> 
> 
> 
> P.Hansford@elsevier.co.uk on 10/03/2001 09:29:59 AM
> 
> Please respond to P.Hansford@elsevier.co.uk
> 
> To:   Info-VAX@mvb.saic.com
> cc:
> Subject:  Reset error account on Alpha
> 
> 
> 
> 
> Hi
> I was wondering if there was any official or even unofficial utility or
> piece of Freeware to reset the error count on Alphas apart from the possibly
> perilous process of SDA and Delta debugger to zap the contents of
> UCB+UCB$L_ERRCNT.
> Cheers
> Paul
> **Paul Hansford
> **Elsevier Science UK
> **p.hansford@elsevier.co.uk