From: kuhrt@encompasserve.org
Sent: Friday, June 15, 2001 1:51 PM
To: Info-VAX@Mvb.Saic.Com
Subject: TCPIP$ logcials for CSWS CGI

For those of you running Apache (CSWS) with Multinet, you have to
define TCPIP$ logicals to match the UCX$ logicals to get CGI to work
properly.  Here is a quick command proc to find all the UCX$ logicals
and create TCPIP$ logicals to match.

It works for me, but hasn't been extensively tested.  Your milage may 
vary.

$ pid = f$getjpi( "", "PID")
$ tmp = "ucx2tcpip_logs_" + pid + ".tmp"
$ table = ""
$ dblq = """
$ def/user sys$output 'tmp'
$ sho log ucx$*
$ open file 'tmp'
$read_loop:
$    read/end=eof file rec
$    rec = f$edit( rec, "COLLAPSE")
$    if f$locate( "LNM$", rec) .nes. f$length( rec)
$    then
$       table = rec - "(" - ")"
$       goto read_loop
$    endif
$    if f$locate( "UCX$", rec) .eqs. f$length( rec) then goto read_loop
$    left = f$element( 0, "=", rec)
$    tran = f$trnlnm( 'left)
$    newt = "TCPIP$" + ( left - "UCX$") - dblq - dblq
$    newt = dblq + newt + dblq
$    tran = dblq + tran + dblq
$    define/table='table 'newt 'tran
$    goto read_loop
$eof:
$ close file
$ deletex/nolog 'tmp';*
$ exit