Article 6050 of alt.sources:
Path: jac.zko.dec.com!crl.dec.com!crl.dec.com!bloom-beacon.mit.edu!panix!news.mathworks.com!europa.chnt.gtegsc.com!howland.reston.ans.net!news.cac.psu.edu!news.pop.psu.edu!ra.nrl.navy.mil!mitch.nrl.navy.mil!grunes
From: grunes@news.nrl.navy.mil (Mitchell R Grunes)
Newsgroups: alt.sources
Subject: diagramf: Simple Diagrammer for Fortran Language Programs: Update
Date: Wed, 28 Jun 1995 20:42:22 GMT
Organization: AlliedSignal Technical Services Corp.
Lines: 622
Message-ID: <grunes.257.804372142@news.nrl.navy.mil>
NNTP-Posting-Host: mitch.nrl.navy.mil

Archive-name: diagramf
Submitted-by: grunes@nrlvax.nrl.navy.mil (Mitchell R Grunes)

****diagramf: Simple Diagrammer for Fortran Language Programs****

The most recent changes:
  Improve the way CASE constructs are diagrammed.
  Tries to recognize some Fortran 90 structures,
   but I haven't tested that, and it probably doesn't work.
  Allow you to choose IBM PC graphics symbols instead of +, | and -.

If you like or dislike it, send e-mail.  DON'T POST to alt.sources.
Sorry, little or no help can be provided for this program, and
I can't find problems without an example of where it failed.
Early versions were called "diagram".

CONTENTS:
  diagramf.for     Fortran language source code.
  diagramf.bat     Sample MS-DOS procedure to run without answering
                   questions. Executable must be in c:\grunes.
---diagramf.for--------------CUT HERE-----------------------------
c EXAMPLE OF OUTPUT (looks better with IBM PC graphics):

c     +---------------subroutine a(x)                  |   1
c     |+--------------do i=1,5                         |   2
c     ||+---------------if(i/2*2.eq.i)then             |   3
c     |||                 x(i)=1                       |   4
c     ||+---------------else                           |   5
c     |||                 x(i)=2                       |   6
c     ||+---------------endif                          |   7
c     |+--------------enddo                            |   8
c     +---------------end                              |   9

c Diagrams FORTRAN if-else-elseif-endif, do-enddo and case constructs,
c  start and end of routines, type definitions, modules and interfaces;
c  puts a * next to goto, return, cycle, exit, stop, end= and err=.

c Program by Mitchell R Grunes, ATSC/NRL (grunes@nrlvax.nrl.navy.mil).
c Revision date: 6/28/95.
c If you find it useful, please send me an e-mail comment.

c This program was written in FORTRAN, the One True Language.

c Note--this is a quick and dirty attempt--may not always work quite right.

c **WARNING**The Fortran 90/95 features have not been tested at all,
c            and probably won't work.

c It can also be confused if an INCLUDE block contains a structure that
c  begins inside and ends outside (or vice-versa).

c I hope this works for you, but bear in mind that nothing short of
c  a full-fledged language parser could really do the job.  Perhaps
c  worth about what you paid for it.    (-:

c Versions: To diagram Fortran: diagramf.for
c                      IDL:     diagrami.for
c                      C:       diagramc.for
c MS-DOS procedures to call above programs without asking so many questions,
c  append output to file diagram.out:
c                       Fortran: diagramf.bat
c                       IDL:     diagrami.bat
c                       C:       diagramc.bat

        program diagramf                        !Diagrammer for Fortran
        character*80 filnam,filnam2

        print*,'FORTRAN source filename?'
        read(*,'(a80)')filnam
        print*,filnam

        print*,'Output file (blank=screen)?'
        read(*,'(a80)')filnam2
        print*,filnam2

        print*,'Column in which to write line #''s ',
     &   '(0 for none; 67 for 80 col screen; 73 to show card format):'
        read*,LCol
        print*,LCol

        print*,'Embed include files (0=no):'
        read*,iembed
        print*,iembed

        print*,'Free format (no special meanings to columns 1-6,'
        print*,' c in column 1 does not indicate a comment),'
        print*,' may extend past column 72) (0=no):'
        read*,ifree
        print*,ifree

        print*,'Use IBM PC graphics characters (0=no):'
        read*,igraphics
        print*,igraphics

        call diagram(filnam,filnam2,LCol,iembed,ifree,igraphics)
        end
c-----------------------------------------------------------------------
        subroutine diagram(filnam,filnam2,LCol,iembed,ifree,igraphics)
        character*80 filnam,filnam2
        character*160 a,b
        character*16 aa
        character*5 form
        character*8 fm
        character*1 c,c2
        logical find
        external find
        common icol,icol1
        character*10 label(100)
        logical fout

c Define Block symbols:
        character*1 BlockBegin   (2) /'+','+'/
        character*1 BlockEnd     (2) /'+','+'/
        character*1 BlockElse    (2) /'+','+'/
        character*1 BlockContinue(2) /'|','|'/
        character*1 BlockHoriz   (2) /'-','-'/

        if(igraphics.ne.0)then
          iGraphics=1

          BlockBegin   (1)=char(218)            ! (1)=normal
          BlockEnd     (1)=char(192)
          BlockElse    (1)=char(195)
          BlockContinue(1)=char(179)
          BlockHoriz   (1)=char(196)

          BlockBegin   (2)=char(214)            ! (2)=DO/FOR loops (doubled)
          BlockEnd     (2)=char(211)            ! (not yet used)
          BlockEnd     (2)=char(211)
          BlockElse    (2)=char(199)
          BlockContinue(2)=char(186)
          BlockHoriz   (2)=char(196)
        endif

        open(1,file=filnam,status='old')
        fout=filnam2.gt.' '
        if(fout)open(2,file=filnam2,status='unknown')
                                                !ASCII 12 is a form feed
        if(fout)write(2,*)char(12),
     &   '=============--',filnam(1:LenA(filnam)),'--============='
        if(fout)     write(2,'(1x,a57,a49)')
     &   '       ....,....1....,....2....,....3....,....4....,....5',
     &          '....,....6....,....7....,....8....,....9....,....'
        if(.not.fout)write(*,'(a57,a49)')' ',
     &   '       ....,....1....,....2....,....3....,....4....,....5',
     &          '....,....6....,....7....,....8....,....9....,....'

        aa=' '
        do i=1,15,2
          aa(i:i)=BlockContinue(1)
        enddo

        i1=0                                    !# of nest levels before current line
        i2=0                                    !# of nest levels on  current line
        i3=0                                    !# of nest levels after current line
        i4=0                                    !1 to flag start or end of block
        InSub=0                                 !Inside a subroutine, function or mainline
        InMod=0                                 !Inside module or contains
        nMain=0                                 !no mainline program yet
        nlabel=0                                !# of labels for do loop ends
        iAlphaNum=0                             !Last char of line is alpha-numeric
        nline=0
        iunit=1
10      a=' '
        read(iunit,'(a160)',end=99)a
        nline=nline+1
        fm=' '
        write(fm,'(i5)')nline
        form=fm
        !if(nline/100*100.eq.nline.and.fout)print*,'Line ',form

        if(a(1:1).eq.char(12))then
          if(fout)write(2,'(a1,:)')char(12)
          if(.not.fout)print*,'------------FORM FEED------------'
          b=a(2:160)
          a=b
        endif

        b=' '                                   !turn tabs to spaces
        j=1
        do i=1,160
          if(a(i:i).eq.char(9))then
            j=(j-1)/8*8+8+1
          elseif(j.le.160)then
            b(j:j)=a(i:i)
            j=j+1
          endif
        enddo

        a=' '                                   !Pre-processed output
        i=1                                     !Some basic pre-processing
        j=1
        iquote=0                                !no ' yet
        idquote=0                               !no " yet
        i72flag=0                               !nothing over column 72 yet
        iOldAlphaNum=iAlphaNum                  !last line ended in alpha-numeric?
        iAlphaNum=0
        iContinue=0                             !continued line?
        if(find(b,'&',2))icontinue=1
        j=1
        if((b(1:1).eq.'c'.or.b(1:1).eq.'C').and.ifree.eq.0)goto 15 !comment line
        do i=1,160
          c=b(i:i)
          if(c.ge.'A'.and.c.le.'Z')c=char(ichar(c)+32)  !handle upper case
                                                !ASCII 33 is '!'
          if(c.eq.char(33).and.iquote.eq.0.and.idquote.eq.0)goto 15
          if(i.gt.72.and.i72flag.eq.0.and.c.ne.' '.and.ifree.eq.0)then
            i72flag=1
            PRINT*,'***WARNING--PAST COLUMN 72 at line',form
            print*,char(7)
          endif
          if(i.eq.6.and.c.ne.' '.and.ifree.eq.0)iContinue=1
          if((i.gt.6.or.ifree.ne.0).and.c.ne.' ')then   !Used to look for identifiers
            iAlphaNum=0                                 ! that wrap between lines.
            if((c.ge.'a'.and.c.le.'z').or.
     &       (c.ge.'0'.and.c.le.'9'.and.ifree.eq.0))then
              iAlphaNum=1
              if(iContinue.eq.1)then
                if(iOldAlphaNum.ne.0)then
                  PRINT*,'***POSSIBLE SPLIT IDENTIFIER at line',form
                  print*,char(7)
                endif
              endif
            endif
            iContinue=2
          endif

          if(c.eq.''''.and.(i.ne.6.or.ifree.ne.0).and.idquote.eq.0)
     &     iquote=1-iquote
          if(c.eq.'"' .and.(i.ne.6.or.ifree.ne.0).and.iquote .eq.0)
     &     idquote=1-idquote
          if(iquote.eq.1)then
            if(find(a,'include ',2).and.iembed.ne.0)then
              iquote=0
              idquote=0
            endif
          endif
          if(iquote.ne.0.or.idquote.ne.0)c=' '
          if(j.gt.1)then                        !(kill multiple spaces,& around =)
            c2=a(j-1:j-1)
            if(c.eq.' '.and.c2.eq.' ')j=j-1
            if(c.eq.'='.and.c2.eq.' ')j=j-1
            if(c.eq.' '.and.c2.eq.'=')j=j-1
            if(c.eq.' '.and.c2.eq.'=')c='='
          endif
          a(j:j)=c
          j=j+1
        enddo

15      i2=i1
        i3=i1
        i4=0
        igoto=0                                 !no goto on line

        if(a.ne.' '.and.InSub.eq.0..and..not.
     &   (find(a,'function ',4).or.find(a,'subroutine ',4).or.
     &    find(a,'program ',2).or.
     &    find(a,'block data ',2).or.find(a,'blockdata ',2)))then
          nMain=nMain+1                         !mainline
          InSub=InSub+1
          if(fout)print*,'Line ',form,' ',b(1:LenA(b))
          if(nMain.gt.1)then
            PRINT*,'***ERROR--TOO MANY MAINLINES***'
            if(fout)WRITE(2,*)'***ERROR--TOO MANY MAINLINES!***'
            print*,char(7)
          endif
          i4=i4+1
          i2=i2+1
          i3=i3+1
        endif

        if(find(a,'go to',1+8+64).or.find(a,'goto',1+8+64).or.
     &     find(a,'end=',1+16).or.find(a,'err=',1+16).or.
     &     find(a,'return',1+8+64).or.find(a,'cycle ',1+8+64).or.
     &    (find(a,'exit ',1+8+64).and..not.find(a,'call ',0)).or.
     &     find(a,'stop  ',1+8+64))
     &  igoto=1
        if(find(a,'include ''',2).and.iembed.ne.0)then
          filnam=a(icol:160)
          if(.not.find(filnam,'''',0))goto 20
          filnam(icol-1:80)=' '
          if(fout)print*,'including file ',filnam(1:50)
          close(3)
          open(3,file=filnam,status='old',err=17)
          iunit=3
          nlinesave=nline
          nline=0
          i2=i2+1
          i3=i3+1
          i4=i4+1
          goto 20
17        PRINT*,'***WARNING--Missing include file***'
          print*,char(7)
        elseif(find(a,'endmodule ',2).or.find(a,'end module ',2).or.
     &      find(a,'endinterface',2).or.find(a,'end interface',2))then
          i3=i3-1
          i4=i4+1
          InMod=InMod-1
        elseif(find(a,'enddo  ',256).or.find(a,'end do  ',256))then
          i3=i3-1
          i4=i4+1
          nlabel=nlabel-1
        elseif(find(a,'endif  ',256).or.find(a,'end if  ',256).or.
     &         find(a,'endtype ',2).or.find(a,'end type ',2).or.
     &         find(a,'endselect ',256).or.find(a,'end select ',256).or.
     &         find(a,'endforall ',256).or.
     &         find(a,'end forall ',256).or.find(a,'end where ',256)
     &         )then
          i3=i3-1
          i4=i4+1
        elseif(find(a,'end  ',256).or.
     &         find(a,'end function ',256).or.
     &         find(a,'end subroutine ',256).or.
     &         find(a,'end program ',256).or.
     &         find(a,'end block',256))then
          i3=i3-1
          i4=i4+1
          InSub=InSub-1
          if(InSub.lt.0.or.(InSub.gt.0.and.InMod.le.0))then
            PRINT*,'***ERROR--INVALID DIAGRAMMING INDEX line',form
            if(fout)WRITE(2,*)'***ERROR--INVALID DIAGRAMMING INDEX!***'
            print*,char(7)
          endif
          if(i3.eq.0)InSub=0
        elseif(find(a,'then  ',1+8))then
          i4=i4+1
          if(.not.(find(a,'else if',128+256).or.
     &             find(a,'elseif', 128+256)))then
            i2=i2+1
            i3=i3+1
          endif
        elseif(find(a,'elseif',128+256).or.
     &         find(a,'else if',128+256))then
          i4=i4+1
          i3=i3-1
        elseif(find(a,'else  ',256).or.find(a,'entry ',4).or.
     &         find(a,'case ',256).or.
     &         find(a,'elsewhere  ',256).or.
     &         find(a,'else where  ',256))then
          i4=i4+1
        elseif((find(a,'type ',2).and..not.find(a,'(',0)).or.
     &          find(a,'selectcase',256).or.
     &          find(a,'select case',256).or.
     &          find(a,'forall (',256).or.find(a,'forall (',256).or.
     &          find(a,'where (',256))then
          i2=i2+1
          i3=i3+1
          i4=i4+1
        elseif(find(a,'module ',2).or.find(a,'contains ',2).or.
     &          find(a,'interface ',2))then
          if(fout)print*,'Line ',form,' ',b(1:LenA(b))
          i2=i2+1
          i3=i3+1
          i4=i4+1
          InMod=InMod+1
        elseif(find(a,'dowhile',128+256).or.
     &         find(a,'do while',128+256))then
          i2=i2+1
          i3=i3+1
          i4=i4+1
          !icol2=icol&&&
          nlabel=nlabel+1
          label(nlabel)='####'
        elseif(find(a,' do ',256).or.
     &   (ifree.ne.0.and.a(1:3).eq.'do '))then
          if(icol1.lt.7.or.a(7:max(7,icol1)).eq.' '.or.
     &     (ifree.ne.0.and.a(1:3).eq.'do '))then
            i2=i2+1
            i3=i3+1
            i4=i4+1
            icol2=icol
            dowhile(icol2.lt.159.and.a(icol2:icol2).eq.' ')
              icol2=icol2+1
            enddo
            c=a(icol2:icol2)
            if(find(a(icol2:160),' ',0).and.c.ge.'0'.and.c.le.'9')then
              nlabel=nlabel+1
              label(nlabel)=a(icol2:icol2+icol-2)
            else
              nlabel=nlabel+1
              label(nlabel)='####'
            endif
          endif
        elseif(find(a,'function ',4).or.find(a,'subroutine ',4).or.
     &         find(a,'program ',2) .or.
     &         find(a,'block data ',2).or.find(a,'blockdata ',2))then
          if(fout)print*,'Line ',form,' ',b(1:LenA(b))
          InSub=InSub+1
          i2=i2+1
          i3=i3+1
          i4=i4+1
          if(InSub.eq.1.and.i3.ne.1.and.InMod.le.0)then
            PRINT*,'***ERROR--INVALID DIAGRAMMING INDEX line',form
            if(fout)
     &       WRITE(2,*)'***ERROR--INVALID DIAGRAMMING INDEX!***'
            print*,char(7)
            i3=1
          endif
        endif

20      if(b(1:5).ne.' '.or.ifree.ne.0)then     ! Search for DO labels
          iend=1
          iflag=0
          dowhile(iend.lt.160.and.(b(iend:iend).eq.' '.or.
     &     (b(iend:iend).ge.'0'.and.b(iend:iend).le.'9')))
            if(b(iend:iend).ge.'0'.and.b(iend:iend).le.'9')iflag=1
            iend=iend+1
          enddo
          if(iend.gt.1)iend=iend-1
          if(iflag.ne.0)then
            do i=1,nlabel
              j=nlabel+1-i                      !  (in reverse order)
              jjj=9
              dowhile (label(j)(jjj:jjj).eq.' '.and.jjj.gt.1)
                jjj=jjj-1
              enddo
              if(find(b(1:iend),label(j)(1:jjj+1),1))then
                i3=i3-1
                i4=i4+1
                nlabel=j-1
                goto 20
              endif
            enddo
          endif
        endif

        a=' '
        if(i1.lt.0.or.i2.lt.0.or.i3.lt.0.or.i4.lt.0)then
          PRINT*,'***ERROR--INVALID DIAGRAMMING INDEX line',form
          if(fout)WRITE(2,*)'***ERROR--INVALID DIAGRAMMING INDEX!***'
          print*,char(7)
          i1=max(i1,0)
          i2=max(i2,0)
          i3=max(i3,0)
          i4=max(i4,0)
        endif
        jj=max(1,min(16,2*i2-1))
        if(i2.gt.0)a=aa(1:jj)

        iBlock=1                                !for now
        if(i4.ne.0)then
          jjj=1
          dowhile(jjj.lt.160.and.b(jjj:jjj).eq.' ')
            jjj=jjj+1
          enddo
          do jjjj=1,jjj-2
            b(jjjj:jjjj)=BlockHoriz(iBlock)
          enddo
          do jjjj=jj+1,16
            a(jjjj:jjjj)=BlockHoriz(iBlock)
          enddo
          if(jjj.eq.1)a(15:16)=' '
        endif
        do i=0,i4-1
          c=BlockElse(iBlock)
          if(i1+i.lt.i3)c=BlockBegin(iBlock)
          if(i1+i.gt.i3)c=BlockEnd(iBlock)
          a(max(1,min(15,jj-i*2)):max(1,min(15,jj-i*2)))=c
        enddo
        if(LCol.ne.0.and.b(max(1,LCol):160).eq.' ')then
          if(nline.eq.0)write(fm,'(i5)')nlinesave
          form=fm
          if(form(1:1).eq.' ')form(1:1)=BlockContinue(iBlock)
          b(LCol:LCol+4)=form
        endif

        n=LenA(b)
        if(igoto.ne.0)a(13:13)='*'
c loop=last minute change to reduce spaces in diagram block:
        if(fout)     write(2,'(80a1,80a1)')
     &   (a(i:i),i=1,15,2),(b(i:i),i=1,n)
        if(.not.fout)write(*,'(1x,80a1,80a1)')
     &   (a(i:i),i=1,15,2),(b(i:i),i=1,n)
        i1=i3
        goto 10
99      if(iunit.eq.3)then
          iunit=1
          i1=i1-1
          close(3)
          nline=nlinesave
          goto 10
        endif
        if(i3.gt.0.or.InSub.ne.0)then
          PRINT*,'***WARNING--SOME NEST LEVELS LEFT HANGING AT END***'
          print*,char(7)
        endif
        end
c-----------------------------------------------------------------------
        logical function find(a,b,icond)        !find b in a, subject to conditions:
                                                !icond=sum of the following:
                                                !2:  Must be first non-blank
                                                !4:  Prior character, if present,
                                                !    must not be alphanumeric.
                                                !8:  Prior character, if present,
                                                !    must be blank or )
                                                !16: Prior character, if present,
                                                !    must be blank or ,
                                                !32: Next character not alphanumeric
                                                !64: Next character not alphabetic
                                                !128:Next character must be blank or (
                                                !256:1st non-blank, possibly except for
                                                !    numeric labels
c Program by Mitchell R Grunes, ATSC/NRL (grunes@nrlvax.nrl.navy.mil).
c Revision date: 6/28/95.
        character*(*) a,b
        character*1   c,cNext,c2
        common icol,icol1
        logical result

        ii=len(a)
        jj=len(b)
        result=.false.
        do i=1,ii-jj+1
          if(a(i:i+jj-1).eq.b)then              ! Found--Now do tests
            icol1=i                             ! icol1=column of item found
            icol =i+jj                          ! icol =colomn after item found

            c=' '
            cNext=' '
            if(icol1.gt.1)c=a(icol1-1:icol1-1)
            if(icol .le.ii)cNext=a(icol:icol)

            result=.true.
            if(result.and.iand(icond,2).ne.0.and.icol1.gt.1)then
              result=a(1:icol1-1).eq.' '
            endif

            if(result.and.iand(icond,4).ne.0)
     &       result=(c.lt.'0'.or.c.gt.'9').and.(c.lt.'a'.or.c.gt.'z')

            if(result.and.iand(icond,8).ne.0)result=c.eq.' '.or.c.eq.')'

            if(result.and.iand(icond,16).ne.0)
     &       result=c.eq.' '.or.c.eq.','

            if(result.and.iand(icond,32).ne.0)
     &       result=(cNext.lt.'0'.or.cNext.gt.'9').and.
     &              (cNext.lt.'a'.or.cNext.gt.'z')

            if(result.and.iand(icond,64).ne.0)
     &       result=(cNext.lt.'a'.or.cNext.gt.'z')

            if(result.and.iand(icond,128).ne.0)
     &       result=cNext.eq.' '.or.cNext.eq.'('

            if(result.and.iand(icond,256).ne.0.and.icol1.gt.1)then
              ii=1
              do iii=1,icol1-1
                c2=a(iii:iii)
                if(c2.ge.'0'.and.c2.le.'9')ii=iii+1
                if(c2.ne.' '.and.(c2.lt.'0'.or.c2.gt.'9'))goto 20
              enddo
20            if(ii.lt.icol1)then
                result=a(ii:icol1-1).eq.' '
              endif
            endif

            find=result
            if(result)return
          endif
        enddo
        find=result
        end
c-----------------------------------------------------------------------
        function LenA(a)                        ! Length of string, at least 1
c Program by Mitchell R Grunes, ATSC/NRL (grunes@nrlvax.nrl.navy.mil).
c Revision date: 6/28/95.
        character*(*) a
        n=len(a)
        dowhile(n.gt.1.and.a(n:n).eq.' ')
          n=n-1
        enddo
        LenA=n
        end
---diagramf.bat--------------CUT HERE-----------------------------
rem procedure to diagram a FORTRAN language program

rem  by Mitchell R Grunes.

rem I assume that the executable is in directory c:\grunes on
rem  your PC.

rem Syntax:
rem     diagramf
rem to be prompted for input parameters.

rem Alternate Syntax:
rem     diagramf filename(s)
rem to append diagram of file(s) into diagram.out

if %1a == a  c:\grunes\diagramf
if %1a == a  goto quit

echo off
:loop

  echo ========================-- %1 --========================
  rem Prompt answers: input from %1, output to diagram2.sc (for now),
  rem  place numbers in column 73, embed include files, don't use free
  rem  format, use IBM PC graphics.

  echo %1          >  diagram.sc
  echo diagram2.sc >> diagram.sc
  echo 73          >> diagram.sc
  echo 1           >> diagram.sc
  echo 0           >> diagram.sc
  echo 1           >> diagram.sc
  c:\grunes\diagramf < diagram.sc
  type diagram2.sc >> diagram.out
  del diagram.sc
  del diagram2.sc
  shift
  if not %1a == a goto loop

:quit
-----------------------------CUT HERE-----------------------------
-------------------------------------------------------------------------
  Opinions are mine alone.
  I am not a "Real Programmer".  I only program in the Real World.
  Mitchell R Grunes (grunes@nrlvax.nrl.navy.mil)
  AlliedSignal Technical Services Corp.



