          <<< NOTED::DISK$NOTES7:[NOTES$LIBRARY_7OF4]HACKERS.NOTE;1 >>>
                               -< ** Hackers ** >-
================================================================================
Note 138.25              changing USERNAMEs and PROMPTs                 25 of 29
AZTECH::LASTOVICA "Does the name Pavlov ring a bell" 39 lines  24-JAN-1995 09:53
                              -< one alternative >-
--------------------------------------------------------------------------------
	.TITLE	SETUSER
	.IDENT	'V03-000'
	.LIBRARY /SYS$LIBRARY:LIB/

$CLIREQDESC
$JIBDEF
$PCBDEF

	.PSECT	$OWN$,NOEXE,2

GET_COMMAND:
	.BYTE	1
	.BYTE	0,0,0
	.LONG	0,0,0,0,0,0

	.PSECT	$CODE$,NOWRT,2

	.ENTRY	SET_USER,^M<>

	CLRQ	-(SP)
	PUSHAB	GET_COMMAND
	CALLS	#3,@8(AP)
	CLRL	-(SP)
	PUSHAB	WRITE_NAME
	CALLS	#2,@#SYS$CMKRNL
	RET

	.ENTRY	WRITE_NAME,^M<R2,R3,R4,R5,R6,R7>

	MOVAB	GET_COMMAND,R6
	MOVC5	CLI$W_RQSIZE(R6),@CLI$A_RQADDR(R6),#32,#12,@#CTL$T_USERNAME
	MOVL	@#CTL$GL_PCB,R0
	MOVL	PCB$L_JIB(R0),R7
	MOVC5	CLI$W_RQSIZE(R6),@CLI$A_RQADDR(R6),#32,#12,JIB$T_USERNAME(R7)
	MOVL	#SS$_NORMAL,R0
	RET

	.END	SET_USER
    
