From:	CRDGW2::CRDGW2::MRGATE::"SMTP::CRVAX.SRI.COM::RELAY-INFO-VAX" 23-OCT-1989 18:11
To:	MRGATE::"ARISIA::EVERHART"
Subj:	Re: Need HELP on ftp from multinet to wintcp

Received: From TGV.COM by CRVAX.SRI.COM with TCP; Mon, 23 OCT 89 14:39:03 PDT
Date:     Mon, 23 Oct 89 14:39:27 PDT
From: adelman@TGV.COM (Kenneth Adelman)
Reply-To: Adelman@TGV.COM (Kenneth Adelman)
Message-Id: <891023143925.20200055@TGV.COM>
Subject:  Re: Need HELP on ftp from multinet to wintcp
To: info-vax@sri.com
Cc: RMCEWEN@rcca.bbn.com

	Oops. Left off this short program to set the record size to 2048.

							Ken

        .title  set2048  set mrs=2048
        $atrdef
        $fabdef
        $iodef
        .library        /SYS$LIBRARY:LIB/
        $fatdef
        .default        displacement,long
        .psect  set2048,nowrt,exe,shr,pic,long
        .entry  set2048,^m<>
        pushab  buf
        pushl   #buflen
        clrl    -(sp)
        pushaw  (sp)
        pushaq  prompt
        pushaq  12(sp)
        calls   #3,g^lib$get_foreign
        blbs    r0,1$
        cmpl    r0,#rms$_eof
        bneq    2$
        movl    s^#ss$_normal,r0
2$:     ret
1$:     movl    (sp)+,r1
        movb    r1,fab+fab$b_fns
        movab   buf,fab+fab$l_fna
        $open   fab=fab
        blbc    r0,10$
        clrl    -(sp)
        pushaw  attr
        clrq    -(sp)
        clrq    -(sp)
        clrq    -(sp)
        pushaq  iosb
        pushl   #io$_access
        movzwl  fab+fab$l_stv,-(sp)
        clrl    -(sp)
        calls   #12,@#sys$qiow
        blbc    r0,10$
        movzwl  iosb,r0
        blbc    r0,10$
        movw    #2048,fat+fat$w_rsize
        movw    #2048,fat+fat$w_maxrec
        clrl    -(sp)
        pushaw  attr
        clrq    -(sp)
        clrq    -(sp)
        clrq    -(sp)
        pushaq  iosb
        pushl   #io$_deaccess
        movzwl  fab+fab$l_stv,-(sp)
        clrl    -(sp)
        calls   #12,@#sys$qiow
        blbc    r0,10$
        movzwl  iosb,r0
10$:    ret
        .psect  variables,wrt,noexe,noshr,long
iosb::  .blkl   2
fab::   $fab    fac=<put>,-
                fop=<sqo,ufo>,-
                rtv=1
attr::  .word   fat$w_maxrec+2
        .word   atr$c_recattr
        .address        fat
        .long   0
fat::   .blkb   fat$w_maxrec+2
buf::   .blkb   2048
buflen  = .-buf
        .psect  data,nowrt,noexe,shr,long
prompt:: .ascid /Filename: /
        .end    set2048

